Finalize UI

Signed-off-by: Mubashshir <ahm@jadupc.com>

1 files changed, 55 insertions, 0 deletions

diff --git a/meson.build b/meson.build
new file mode 100644
index 0000000..faa901e
--- /dev/null
+++ b/meson.build
@@ -0,0 +1,55 @@
+project('support',
+        ['c', 'vala'],
+        version: '0.1.0',
+        meson_version: '>= 0.52.0',
+        license: 'GPL-3.0-or-later',
+        default_options: [
+            'warning_level=2',
+            'werror=false',
+        ],
+)
+
+description = '''JaduPc Remote Support Console'''
+desktop_name = 'JaduPc Remote Support Console'
+
+
+if get_option('debug')
+  add_project_arguments('-DG_LOG_USE_STRUCTURED=1',  language : 'c')
+  add_project_arguments('--debug',  language : 'vala')
+endif
+
+maintainer_rname = 'com.jadupc'
+project_name = meson.project_name ()
+application_id = '@0@.@1@'.format (maintainer_rname, project_name)
+application_path = '/'.join([''] + application_id.split('.'))
+application_name = '@0@-@1@'.format(maintainer_rname.split('.').get(-1), project_name)
+
+i18n = import('i18n')
+gnome = import('gnome')
+
+valac = meson.get_compiler ('vala')
+conf  = configuration_data ()
+
+srcs = []
+i18n_data = []
+
+conf.set_quoted ('GETTEXT_PACKAGE', application_name)
+conf.set_quoted ('DATADIR', get_option ('prefix') / get_option ('datadir'))
+conf.set_quoted ('LOCALEDIR', get_option ('prefix') / get_option ('localedir'))
+conf.set_quoted ('APPLICATION_ID', application_id)
+conf.set_quoted ('VERSION', meson.project_version ())
+conf.set_quoted ('SECURE_PATH', get_option('secure-path'))
+
+config_h = declare_dependency (
+  sources: configure_file (
+    output: 'config.h',
+    configuration: conf
+  )
+)
+
+config_h_dir = include_directories ('.')
+config_dep   = valac.find_library ('config', dirs: meson.current_source_dir() / 'src')
+
+subdir('data')
+subdir('src')
+subdir('po')